Weitere Beispiele für Handelssysteme

Double Regression Index (DRI)

Dieses Handelssystem basiert auf der Kreuzung zweier unterschiedlicher Regressionssteigungen (Trends). Die beiden Linien werden voneinander subtrahiert, so dass eine Linie zu sehen ist, die die Null-Linie kreuzt.

Formel:

CODE

$c:=close;
$gd:=$c.gd[$GD_Zeitraum];
$tc:=$c.RegressionsSteigung[$Trend_Zeitraum];
$tgd:=$gd.RegressionsSteigung[$Trend_Zeitraum];
$dri:=$tc-$tgd;

HandelsSystem[
$dri.hl[0];
  $dri.breaks[0;false]
    and
  $tgd>$tgd.before[1];
  $dri.breaks[0;true];
  _;_;
  4;
  $Leerverkäufe_einbeziehen;
  $Spesen;
  $Losslimit]

Dynamic Regression Line (DRL)

Dieses Handelssystem vergleicht die Regressionssteigung der Schlusskurse mit deren Gleitendem Durchschnitt. Bei Kreuzung werden entsprechende Signale generiert.

Formel:

CODE

$c:=close;

$trend:=$c.RegressionsSteigung[$Trend_Perioden];
$t0:=$trend-$trend.minimum[heute-$Normierungszeitraum;heute];
$tnorm:=100/$t0.maximum[heute-$Normierungszeitraum;heute];
$t100:=$t0*$tnorm;

$gd:=$c.gd[$GD_Perioden];
$g0:=$gd-$gd.minimum[heute-$Normierungszeitraum;heute];
$gnorm:=100/$g0.maximum[heute-$Normierungszeitraum;heute];
$g100:=$g0*$gnorm;

$drl:=$t100-$g100;

HandelsSystem[
  $drl;
  $drl.breaks[0;false];
  _;
  $drl.breaks[0;true];
  _;
  4;
  $Leerverkäufe_einbeziehen;
  $Spesen;
  $Losslimit]

Smoothed Overbought/Oversold (SOBOS)

Dieses Handelssystem glättet den OBOS und überprüft, ob sich dieser über einen bestimmten Zeitraum unter/über der Signallinie befindet. Bei Ausbruch aus diesem Tief-/Hochstand werden Signale generiert.

Formel:

CODE

$indi:=close.OBOS[$OBOS_Zeitraum].gd[$GD_Zeitraum];
$pmax:=$indi.PeriodenMaximum[$PMax_Zeitraum];
$pmin:=$indi.PeriodenMinimum[$PMin_Zeitraum];

HandelsSystem[
  $indi.linesmulti[$pmax;$pmin].hl[30;70];
  $pmax<$Level_unten;
  _;
  $pmin>$Level_oben;
  _;
  4;
  $Leerverkäufe_einbeziehen;
  $Spesen;
  $Losslimit]